Bioequivalence and Bioavailability Forum

Hi John,

you talk about a crossover study with more than two treatments, right?
What SAS code did you use that failed? Any error messages?

Mine for the evaluation of crossover studies with more than 2 formulations is (all effects fixed model, Proc GLM):
* the ODS statement saves the differences of least square means;
ODS output LSMeanDiff=_ratios;
Proc GLM data=yourData;
  class tmt period sequence subject;
  * common model;
  model logPK = tmt period sequence subject(sequence)/ss3;
  * test the sequence effect with the right denominator
     may be also coded via a random statement;
  TEST H=sequence E=subject(sequence);
  * least square means + 90% CI of differences;
  LSMeans tmt /cl pdiff alpha=0.1;
run; quit;
* back transformation to the original domain.
  coding T1,T2,T3 and R assumed.
  interest in pairs Tx vs. R only;
data _ratios;
  set _ratios;
  * percent rounded to 2 decimals;
  * must change the sign due to lexical ordering;
  point=round(100*exp(-difference),0.01);
  lower=round(100*exp(-upperCL),0.01);
  upper=round(100*exp(-lowerCL),0.01);
  pair=compress(_tmt)||" vs. "||compress(tmt);
  where tmt='R';
run;
title "90% Confidence intervals";
Proc Print data=_ratios noobs;
  var pair point lower upper;
run;
Replace logPK with your variables containing the log-transformed PK metrics under evaluation.

If you have coded your treatments/formulations with T1, T2, T3 and R the LSMeans statement will give you the differences R-T1, R-T2 and R-T3 and the pairs Tx-Ty as well in lexical order. Therefore you have to change the sign and swap upper/lower limits to get R-Tx. If you are also interested in Tx-Ty modify the code to not change the sign for these pairs.

If you are not interested in sequence effect, drop it from the GLM code.
The 90% confidence intervals are the same.

Eventually you should consider an alpha-adjustment or Dunetts test. See
Hauschke, Steinijans, Pigeot
"Bioequivalence Studies in Drug Development"
Wiley, Chichester (2007)
Chapter 7 "Designs with more than two formulation", 7.4 "Multiplicity"

Hope this helps.