Williams design 3-way [Design Issues]

posted by vezz – Erba (CO), Italy, 2021-06-11 18:56 (1042 d 18:31 ago) – Posting: # 22411
Views: 8,588

❝ I was a little bit hesitant to answer, as I am and likely will remain a noob in the statistical background. Maybe I also misunderstand your question, which is quite possible.

❝ But there are a lot of people around here to correct the answer, if necessary, and its SOP-Friday...

❝

❝ I think I get your point, but I also think that the period effect is implemented above.

❝ The numbers already include both as mean=µ+π = treatment + period effect.


Hi Relaxation and Helmut,

the period effect was taken into account by Helmut when generating the data, but not when analysing them.

I am not able to explicitly describe each single step behind the estimation of the regression model (this would take some time!), but I will share with you the SAS code replicating the example.

Some notes:
- Treatments are coded as 1-2-3 instead of A-B-C.
- Without loss of generality, I am assuming 6 subjects per sequence and with the PARMS statement in the MIXED procedure I keep the residual variance fixed at 10.
- In the first MIXED procedure a model not including the period effect is estimated, while in the second one the model includes the period effect.

data a01 (drop=i t1-t3);
   input t1 t2 t3;
   seq+1;
   do i=1 to 6;   
      subj+1;
      period=1; tmt=t1; output;
      period=2; tmt=t2; output;
      period=3; tmt=t3; output;
   end;
   datalines;
   1 2 3
   2 1 3
   3 1 2
   3 2 1
   ;
run;

data a02;
   set a01;
   y=1*(period=1)+.5*(period=2)+1.5*(period=3);
run;

proc mixed data=a02;
   class seq subj tmt;
   model y = seq subj(seq) tmt;
   parms 10 / hold=1;
   lsmeans tmt / diff;
run;

proc mixed data=a02;
   class seq subj period tmt;
   model y = seq subj(seq) period tmt;
   parms 10 / hold=1;
   lsmeans tmt / diff;
run;

Estimated treatment differences (SE) by the first model (no period effect):
- A vs. B: 3.89E-16 (0.9129)
- A vs. C: -0.3750 (0.9129)
- B vs. C: -0.3750 (0.9129)

Estimated treatment differences (SE) by the second model (period effect included):
- A vs. B: 3.7E-16 (0.9129)
- A vs. C: -753E-17 (1.0206)
- B vs. C: -79E-16 (1.0206)

We may notice that in the second model:
- The estimate of the treatment effect is always practically 0, therefore unbiased.
- SEs are not identical as the design is not balanced for period.
—
Kind regards,

Stefano

Complete thread:

UA Flag
Activity
 Admin contact
22,987 posts in 4,824 threads, 1,663 registered users;
79 visitors (0 registered, 79 guests [including 5 identified bots]).
Forum time: 13:28 CEST (Europe/Vienna)

The only way to comprehend what mathematicians mean by Infinity
is to contemplate the extent of human stupidity.    Voltaire

The Bioequivalence and Bioavailability Forum is hosted by
BEBAC Ing. Helmut Schütz
HTML5