90% confidence interval for R_dnm [Study As­sess­ment]

posted by Shuanghe  – Spain, 2019-01-07 18:11 (1925 d 23:21 ago) – Posting: # 19751
Views: 17,851

Dear Detlew,

❝ Could you please give a detailed example for what you did here?


Sorry. It seems I didn't explain it clearly. My SAS code is almost the same as yours:

PROC MIXED DATA = smith METHOD = ML;
  CLASS subj ;
  MODEL lcmax = ldose / DDFM=SATTERTHWAITE CL ALPHA = 0.1 ;
  RANDOM INTERCEPT / SUBJECT = subj;
  ODS OUTPUT solutionf = out1;
RUN;

I just take the output and calculated some of the numbers according to Smith's article to reproduce his result.

PROC SQL;
  CREATE TABLE result AS
    SELECT
      d2.estimate AS beta1,
      d2.lower AS beta1_l,
      d2.upper AS beta1_u,
      1 + LOG(0.8)/LOG(10) AS dpcrit_l,
      1 + LOG(1.25)/LOG(10) AS dpcrit_u,
      1.25**(1/MAX(1-d2.lower, d2.upper-1)) AS roh1,
      1.25**(1/MAX(d2.lower-1, 1-d2.upper)) AS roh2,
      EXP(d3.estimate + d2.estimate*LOG(250))/EXP(d3.estimate + d2.estimate*LOG(25)) * (25/250) AS R_dnm,     
      10**(d2.estimate-1) AS Rdnm,
      10**(d2.lower-1) AS Rdnm_l,
      10**(d2.upper-1) AS Rdnm_u,
      EXP(d3.estimate + d2.estimate*(LOG(25))) AS dosepred_l,
      EXP(d3.estimate + d2.estimate*(LOG(250))) AS dosepred_h
    FROM out1 AS d2, out1 AS d3
    WHERE UPCASE(d2.effect) EQ "LDOSE" AND
          UPCASE(d3.effect) EQ "INTERCEPT";
  SELECT * FROM result;
QUIT;

This gives (Smith's reported value in blue):

beta1:    0.7615 (0.7615)
beta1_l:  0.6789 (0.679)
beta1_u:  0.8441 (0.844)
dpcrit_l: 0.90309 (0.903)
dpcrit_u: 1.09691 (1.097)

Those are slope and its 90% CI, and the corresponding criteria calculated with dose ratio r = 10 and θL and θU of 0.8 and 1.25, respectively. The rest are for information purpose only.

roh1:        2.003428 (2.0)
roh2:        4.183885 (4.2)
R_dnm:       0.577402 (0.577)
Rdnm:        0.577402 (0.577)
Rdnm_l:      0.477381 (0.477)
Rdnm_u:      0.698378 (0.698)
dosepred_l:  80.92991 (80.9)
dosepred_h:  467.2906 (467)

where R_dnm is the one I used previously, since Smith mentioned in the article that each mean PK was calcuated as exp(beta_0 + beta1*ln(dose)). R_dnm is dose-normalised mean ratio, hence the long line in PROC SQL:
EXP(d3.estimate + d2.estimate*LOG(250))/EXP(d3.estimate + d2.estimate*LOG(25)) * (25/250).
Rdnm is the same thing but calculated with your code which is the one I use now since it's equivalent to previous one but much shorter. I guess that my explanation in previous post with this regard is not clear so I added both of them here. :-D

The last 2 are predicted geometric mean PK values at the dose levels of 25 and 250, as given in the 1st column in Table 2 in Smith's article. These 2nd part of the result are not really necessary to judge dose proportionality (though roh1 and roh2 are useful to know) but as I said, I prefer to reproduce all results as kind of "validation".

By the way, Helmut, I don't know how to make a table (e.g. with 1 row) with heading here so I manually entered all values above; also, I copy/paste greek letter from elsewhere. Is there any helper section with BBCode for special symble and greek letters and table making? I vaguely recall there used to be a section with BBcode examples but couldn't find it now.
—
All the best,
Shuanghe

Complete thread:

UA Flag
Activity
 Admin contact
22,984 posts in 4,822 threads, 1,651 registered users;
42 visitors (0 registered, 42 guests [including 2 identified bots]).
Forum time: 18:32 CEST (Europe/Vienna)

You can’t fix by analysis
what you bungled by design.    Richard J. Light, Judith D. Singer, John B. Willett

The Bioequivalence and Bioavailability Forum is hosted by
BEBAC Ing. Helmut Schütz
HTML5